home *** CD-ROM | disk | FTP | other *** search
/ Shareware Games Galore! / Shareware Games Galore!.iso / arcade / gameser5 / hobbit.bas < prev    next >
Encoding:
BASIC Source File  |  1980-01-01  |  11.8 KB  |  331 lines
  1. 1 'COPYRIGHT (C) CLOAD 1979
  2. 2 'K. WILLIAMS, 3250 VERMONT SW, GRANDVILLE, MI 49418
  3. 5 RANDOMIZE(348)
  4. 8 DEFINT A-Z
  5. 10 DIM H(9,9),M(9,9),A(7),D(14),AC(7),Z(4)
  6. 20 A$="RUBY RED  NORN STONEPALE PEARLOPAL EYE  BLUE FLAMEPALANTIR  SILMARILL     "
  7. 30 D$="SCHLOCK   YNGVI     GOLLUM    MARDUK    LOKI      AZATOTH   DAGON     FENRIS    ABRACAX   SAURON    CTHULHU   SATAN    "
  8. 40 CLS:PRINT"H O B B I T"
  9. 45 FOR Q=1 TO 3000:NEXT Q
  10. 50 CLS
  11. 100 INPUT"DO YOU WANT INSTRUCTIONS";O$
  12. 110 IF O$="YES" OR O$="Y" THEN 2220
  13. 120 INPUT"WHAT RATING (1-NOVICE 9-EXPERT)";N
  14. 130 N=INT(ABS(N)):IF N<1 OR N>9 THEN 120
  15. 140 FOR X=1 TO 9:FOR Y=1 TO 9:H(X,Y)=5:M(X,Y)=1:NEXT Y:NEXT X
  16. 190 REM PUT WARPS
  17. 200 B=20+RND*N
  18. 210 FOR Q=1 TO B
  19. 220 X=RND*9 :Y=RND*9 :R=RND*9 :S=RND*9
  20. 230 IF X=SANDY=R THEN 220
  21. 240 H(X,Y)=R*10+S:NEXT Q
  22. 260 REM PUT DEMONS
  23. 270 B=N+3
  24. 280 FOR Q=1 TO B
  25. 290 GOSUB 2440:H(X,Y)=-Q:D(Q)=1
  26. 300 NEXT Q
  27. 310 REM PUT AMULETS
  28. 320 FOR Q=1 TO 7
  29. 330 GOSUB 2440:H(X,Y)=Q*100:A(Q)=1
  30. 340 AC(Q)=3:NEXT Q
  31. 350 REM PUT RUNESTAFF
  32. 360 GOSUB 2440:H(X,Y)=-1*(RND*(N+3)):D(13)=1:Z(3)=X:Z(4)=Y
  33. 370 REM PUT ORB
  34. 380 GOSUB 2440:H(X,Y)=10*(RND*9)+(RND*9):Z(1)=X:Z(2)=Y:D(14)=1
  35. 390 REM PUT CURSES
  36. 400 FOR Q=1 TO 3:C(Q,1)=1:C(Q,2)=10:C(Q,3)=10:NEXT Q
  37. 430 IF N<7 THEN 470
  38. 440 FOR Q=1 TO N-6:GOSUB 2440:C(Q,2)=X:C(Q,3)=Y:NEXT Q
  39. 470 REM PUT FLARES AND ORACLE
  40. 480 GOSUB 2440:H(X,Y)=4:GOSUB 2440:H(X,Y)=2
  41. 490 REM PUT HOBBIT
  42. 500 GOSUB 2440:K=X:L=Y:PRINT"ALL RIGHT FUR-FOOT "
  43. 510 P=125+RND(12-N)
  44. 511 T=1:G=0:W=0:F=10:GOTO 1530
  45. 520 IF T>P THEN 2120
  46. 530 T=T+1
  47. 540 IF N<7 OR D(14)=0 THEN 650
  48. 550 IF C(1,1)=1 THEN 570
  49. 560 T=T+1
  50. 570 IF C(2,1)=1 THEN 590
  51. 580 G=G-(RND*5)
  52. 590 IF C(3,1)=1 OR A(5)=0 OR D(14)=0 THEN 610
  53. 595 PRINT:PRINT"'YOU ARE UNDER MY POWER NOW...'":FOR Q=1 TO 500:NEXT C
  54. 600 ON (RND*4) GOTO 810,830,850,870
  55. 610 FOR Q=1 TO 3
  56. 620 IF C(Q,2)<>K OR C(Q,3)<>L THEN 640
  57. 630 C(Q,1)=0
  58. 640 NEXT Q
  59. 650 PRINT:INPUT"YOUR MOVE";O$
  60. 651 CLS
  61. 660 IF O$="WAIT" OR O$="WT" THEN 1530
  62. 670 IF O$="NORTH" OR O$="N" THEN 810
  63. 680 IF O$="SOUTH" OR O$="S" THEN 830
  64. 690 IF O$="EAST" OR O$="E" THEN 850
  65. 700 IF O$="WEST" OR O$="W" THEN 870
  66. 710 IF O$="MAP" OR O$="M" THEN 890
  67. 720 IF O$="FLARE" OR O$="F" THEN 1110
  68. 730 IF O$="KILL" OR O$="K" THEN 2030
  69. 740 IF O$="LAMP" OR O$="L" THEN 1200
  70. 750 IF O$="QUIT" OR O$="Q" THEN 1460
  71. 760 IF O$="TELEPORT" OR O$="T" THEN 1420
  72. 770 PRINT"EVEN A STUPID HOBBIT LIKE YOU"
  73. 780 PRINT"CAN DO BETTER THAN THAT"
  74. 790 GOTO 520
  75. 800 REM NORTH
  76. 810 K=K-1
  77. 811 GOSUB 2460
  78. 812 GOTO 1530
  79. 820 REM SOUTH
  80. 830 K=K+1
  81. 831 GOTO 811
  82. 840 REM EAST
  83. 850 L=L+1
  84. 851 GOTO 811
  85. 860 REM WEST
  86. 870 L=L-1
  87. 871 GOTO 811
  88. 880 REM MAP
  89. 890 CLS:PRINT "        1     2     3     4     5     6     7     8     9"
  90. 891 PRINT "    +---+-----+-----+-----+-----+-----+-----+-----+-----+"
  91. 892 FOR X=1 TO 9
  92. 893 PRINT X;"-| ";
  93. 900 FOR Y=1 TO 9
  94. 910 IF M(X,Y)>99 THEN 930
  95. 920 PRINT " ";
  96. 930 PRINT M(X,Y);" ";
  97. 940 IF M(X,Y)>9 OR M(X,Y)<-9 THEN 960
  98. 950 PRINT" ";
  99. 960 NEXT Y
  100. 970 PRINT
  101. 980 NEXT X:PRINT
  102. 985 PRINT"YOU ARE AT (";L;",";K;")":GOSUB 986:GOTO 520
  103. 986 IF G>-1 THEN 990
  104. 987 G=0
  105. 990 PRINT"YOU HAVE";G;"GEMS"
  106. 1000 PRINT"AND THESE AMULETS:"
  107. 1010 FOR Q=1 TO 7
  108. 1020 IF A(Q)=1 THEN 1040
  109. 1030 PRINT" ";MID$(A$,Q*10-9,10),
  110. 1040 NEXT Q
  111. 1050 IF D(13)=1 THEN 1070
  112. 1060 PRINT"  RUNESTAFF",
  113. 1070 IF D(14)=1 THEN 1090
  114. 1080 PRINT"  ORB OF ZOT";
  115. 1090 RETURN
  116. 1100 REM FLARE
  117. 1110 IF F>0 THEN 1140
  118. 1120 PRINT"EVEN A SCATTER-BRAINED HOBBIT LIKE YOU"
  119. 1130 PRINT"SHOULD KNOW WHEN HE IS OUT OF FLARES":GOTO 520
  120. 1140 F=F-1:X=K:Y=L
  121. 1150 FOR Q=-1 TO 1:FOR QQ=-1 TO 1:K=Q+X:L=QQ+Y
  122. 1151 GOSUB 2460
  123. 1159 M(K,L)=H(K,L)
  124. 1160 IF M(K,L)>99 THEN 1170:PRINT" ";
  125. 1170 PRINT M(K,L);"  ";:IF M(K,L)>9 OR M(K,L)<0 THEN 1180:PRINT " ";
  126. 1180 NEXT QQ:PRINT:NEXT Q:K=X:L=Y:GOTO 520
  127. 1190 REM LAMP
  128. 1200 INPUT"WHICH DIRECTION DO YOU SHINE THE LAMP";O$:X=K:Y=L
  129. 1210 IF O$<>"NORTH" AND O$<>"N" THEN 1220
  130. 1211 Q=1:GOTO 1250
  131. 1220 IF O$<>"SOUTH" AND O$<>"S" THEN 1230
  132. 1221 Q=2:GOTO 1250
  133. 1230 IF O$<>"EAST" AND O$<>"E" THEN 1240
  134. 1231 Q=3:GOTO 1250
  135. 1240 IF O$<>"WEST" AND O$<>"W" THEN 770
  136. 1241 Q=4
  137. 1250 PRINT"THE MAGIC LAMP SHINES AND AT ";
  138. 1251 ON Q GOTO 1260,1270,1280,1290
  139. 1260 K=K-1:GOTO 1300
  140. 1270 K=K+1:GOTO 1300
  141. 1280 L=L+1:GOTO 1300
  142. 1290 L=L-1
  143. 1300 GOSUB 2460
  144. 1301 PRINT"(";L;",";K;") YOU SEE ";:M(K,L)=H(K,L)
  145. 1310 IF M(K,L)<0 THEN 1380
  146. 1320 IF M(K,L)>0 THEN 1330
  147. 1321 PRINT"AN EMPTY ROOM":GOTO 1365
  148. 1330 IF M(K,L)>2 THEN 1340
  149. 1331 PRINT"THE ORACLE":GOTO 1365
  150. 1340 IF M(K,L)>4 THEN 1350
  151. 1341 PRINT"THE SPARE FLARES":GOTO 1365
  152. 1350 IF M(K,L)>5 THEN 1360
  153. 1351 PRINT"GEMS":GOTO 1365
  154. 1360 IF M(K,L)>99 THEN 1370
  155. 1361 PRINT"A WARP"
  156. 1365 K=X:L=Y:GOTO 520
  157. 1370 PRINT"THE ";MID$(A$,(M(K,L)/100)*10-9,10):GOTO 1365
  158. 1380 PRINT MID$(D$,-M(K,L)*10-9,10)
  159. 1385 IF K=Z(3) AND L=Z(4) THEN 1365
  160. 1390 PRINT"AND HE IS SO ANGRY HE COMES AFTER YOU"
  161. 1400 H(X,Y)=H(K,L):M(X,Y)=M(K,L):M(K,L)=0:H(K,L)=0:K=X:L=Y:GOTO 1530
  162. 1410 REM TELEPORT
  163. 1420 IF D(13)=0 THEN 1440
  164. 1421 PRINT"LAME-BRAIN HOBBIT MUST BE SUICIDAL"
  165. 1430 PRINT"TO TRY AND TELEPORT WITHOUT THE RUNESTAFF":GOTO 520
  166. 1440 INPUT"X-COORD ";L:IF L<0 OR L>9 THEN 1440
  167. 1441 INPUT"Y-COORD ";K:IF K<0 OR K>9 THEN 1441
  168. 1450 FOR Q=1 TO 7:A(Q)=1:NEXT Q:G=0:M(K,L)=H(K,L):GOTO 1530
  169. 1460 REM QUIT
  170. 1470 INPUT "DID YOU REALLY WANT TO QUIT";O$:IF O$="YES" OR O$="Y" THEN W=1:GOTO 1481
  171. 1480 PRINT"THEN DON'T SAY YOU DO":GOTO 520
  172. 1481 PRINT:IF D(14)=0 AND W=1 THEN PRINT"WELL, LITTLE HOBBIT, YOU WON THIS ONE" ELSE PRINT "TOO BAD YOU DIDN'T WIN, HOBBIT"
  173. 1482 PRINT:GOSUB 986
  174. 1483 PRINT:PRINT"AND YOU KILLED THESE DEMONS:":Q=0
  175. 1484 Q=Q+1:IF D(Q)=0 THEN PRINT MID$(D$,Q*10-9,10),
  176. 1485 IF Q<N+3 THEN 1484
  177. 1486 PRINT
  178. 1490 INPUT"DO YOU WANT TO PLAY AGAIN";O$
  179. 1491 IF O$<>"YES" AND O$<>"Y" THEN 1510
  180. 1500 PRINT"SOME HOBBITS NEVER LEARN":GOTO 100
  181. 1510 PRINT"MAYBE DUMB HOBBIT NOT SO DUMB AFTER ALL"
  182. 1520 GOTO 9999
  183. 1530 PRINT"YOU ARE AT (";L;",";K;")":M(K,L)=H(K,L)
  184. 1540 IF M(K,L)<0 THEN 1850
  185. 1550 IF M(K,L)=0 THEN 1650
  186. 1560 IF M(K,L)=2 THEN 1660
  187. 1570 IF M(K,L)=4 THEN 1630
  188. 1580 IF M(K,L)=5 THEN 1620
  189. 1590 IF M(K,L)<100 THEN 1790
  190. 1600 PRINT"WHERE YOU FIND ";MID$(A$,M(K,L)/10-9,10):A(M(K,L)/100)=0:GOTO 1640
  191. 1620 Q=(RND*5):H(K,L)=0:M(K,L)=0:G=G+Q:IF G>=0 THEN 1622
  192. 1621 G=Q
  193. 1622 PRINT"HERE YOU FIND";Q;"GEMS"
  194. 1623 PRINT"YOU NOW HAVE";G;"GEMS":GOTO 520
  195. 1630 F=F+10:PRINT"HERE YOU FIND THE SPARE FLARES"
  196. 1640 H(K,L)=0:M(K,L)=0:GOTO 520
  197. 1650 PRINT"LOTS OF HOBBIT TRACKS IN THE DUST":GOTO 520
  198. 1660 PRINT"YOU ARE IN THE PRESENCE OF THE ORACLE"
  199. 1670 IF A(4)=1 THEN 1690
  200. 1680 PRINT"THE OPAL EYE COMPELS IT TO ANSWER A QUESTION":GOTO 1720
  201. 1690 IF G>19 THEN 1700
  202. 1691 PRINT"BUT YOU ARE TOO POOR TO ASK ANYTHING":GOTO 520
  203. 1700 INPUT"WILL YOU SPEND 20 GEMS FOR 1 QUESTION";O$
  204. 1710 IF O$<>"YES" AND O$<>"Y" THEN 550 ELSE G=G-20
  205. 1720 PRINT"WHAT WOULD YOU KNOW THE LOCATION OF":X=0:Y=0
  206. 1730 INPUT"(EX: TO FIND THE OPAL EYE TYPE 400)";Q
  207. 1740 FOR R=1 TO 9:FOR S=1 TO 9:PRINT"MUMBLE ";:IF H(R,S)<>Q THEN 1760
  208. 1750 IF Q<>0 THEN M(R,S)=H(R,S):X=R:Y=S:Q=0
  209. 1760 NEXT S:NEXT R:PRINT:PRINT
  210. 1770 IF X<>0 THEN 1780 ELSE PRINT"EVEN THE ORACLE DOES NOT KNOW WHERE THAT IS":GOTO 550
  211. 1780 PRINT"THAT WHICH YOU DESIRE WILL BE FOUND AT (";Y;",";X;")":GOTO 550
  212. 1790 IF K<>Z(1) OR L<>Z(2) THEN 1830
  213. 1800 IF O$<>"TELEPORT" AND O$<>"T" THEN 670
  214. 1810 PRINT"OH WOW!!":PRINT"LUCKY HOBBIT NOW HAS THE MIGHTY ORB OF ZOT!"
  215. 1820 H(K,L)=0:M(K,L)=0:D(14)=0:GOTO 520
  216. 1830 Q=INT(M(K,L)/10):K=M(K,L)-(Q*10):L=Q
  217. 1831 G=G-(RND*5):IF G>-1 THEN 1530 ELSE G=0:GOTO 1530
  218. 1840 REM DEMON
  219. 1850 IF K<>Z(3) OR L<>Z(4) THEN 1870
  220. 1860 PRINT"BOLD HOBBIT THIEF NOW HAS THE RUNESTAFF":H(K,L)=0:M(K,L)=0:D(13)=0:GOTO 520
  221. 1870 M(K,L)=H(K,L):IF M(K,L)>-1 THEN 1530
  222. 1871 PRINT"UH OH - YOU JUST RAN INTO ";MID$(D$,ABS(M(K,L))*10-9,10):Q=0
  223. 1880 Q=Q+1:IF A(Q)=0 THEN 2010
  224. 1881 IF Q<7 THEN 1880
  225. 1890 INPUT"HOW MUCH OF A BRIBE DO YOU OFFER HIM";B:PRINT
  226. 1900 IF B>0 THEN 1930
  227. 1901 PRINT"NORMALLY ";MID$(D$,-M(K,L)*10-9,10);" WOULD EAT YOU,"
  228. 1910 PRINT"BUT HE IS AFRAID THAT YOU ARE SICK OR SOMETHING"
  229. 1920 PRINT"SO TEARS YOU INTO SHREDS INSTEAD":GOTO 1481
  230. 1930 IF B=INT(B) THEN 1960
  231. 1940 PRINT MID$(D$,-M(K,L)*10-9,10);" DOESN'T UNDERSTAND DECIMALS,"
  232. 1950 PRINT"SO HE EATS CONFUSING LITTLE FUR-FOOT":GOTO 1481
  233. 1960 IF B<=G THEN 1990
  234. 1970 PRINT MID$(D$,-M(K,L)*10-9,10);" DOESN'T LIKE HOBBITS WHO OFFER MORE GEMS"
  235. 1980 PRINT"THAN THEY HAVE, SO HE EATS YOU":GOTO 1481
  236. 1990 G=G-B:IF B>(RND*(-M(K,L))) THEN PRINT"HE TAKES YOUR BRIBE":GOTO 550
  237. 1991 PRINT"THAT WASN'T ENOUGH, SO HE EATS YOU":GOTO 1481
  238. 2010 PRINT"BUT THE ";MID$(A$,Q*10-9,10);" PROTECTS YOU":GOTO 520
  239. 2020 REM KILL
  240. 2030 IF M(K,L)<0 THEN 2040
  241. 2031 PRINT"YOU HAVE TO FIND A DEMON TO KILL IT":GOTO 520
  242. 2040 PRINT"WHICH AMULET DO YOU ATTACK WITH"
  243. 2050 INPUT"(EX: OPAL EYE = 400)";Q:IF Q>700 THEN 2050
  244. 2051 Q=Q/100:IF A(Q)=0 THEN 2053
  245. 2052 PRINT"YOU DON'T POSSESS THAT ONE, STUPID!":GOTO 520
  246. 2053 IF AC(Q)>0 THEN 2055
  247. 2054 PRINT "THE ";MID$(A$,Q*10-9,10);" IS RECHARGING":GOTO 520
  248. 2055 AC(Q)=AC(Q)-1
  249. 2060 REM
  250. 2070 PRINT"THE ";MID$(A$,Q*10-9,10);" ATTACKS AND ";MID$(D$,-M(K,L)*10-9,10);
  251. 2080 IF (RND*Q)+3>(RND*-M(K,L)) THEN 2090
  252. 2081 PRINT" IS STAGGERED BUT NOT DEAD":GOTO 520
  253. 2090 PRINT" DIES":B=(RND*50):D(-M(K,L))=0:G=G+B:M(K,L)=0:H(K,L)=0
  254. 2100 PRINT"AND HERE IS HIS HOARD OF";B;"GEMS":GOTO 520
  255. 2110 REM WIZBACK
  256. 2120 IF W>0 THEN 2150
  257. 2121 PRINT"OH NO!!!"
  258. 2130 PRINT"THE WIZARD HAS RETURNED": IF D(14)=1 THEN 2170
  259. 2140 PRINT"BUT THE ORB OF ZOT PROTECTS YOU - FOR NOW":W=RND(9):GOTO 650
  260. 2150 W=W-1:IF W<>0 THEN 650 ELSE PRINT "SOME HOBBITS KNOW WHEN TO QUIT"
  261. 2160 PRINT "YOU DIDN'T."
  262. 2170 PRINT "WHAT A DELICIOUS LOOKING TOAD YOU MAKE":Q=0
  263. 2180 Q=Q+1
  264. 2181 IF D(Q)=1 THEN 2190
  265. 2182 IF Q=12 THEN 2200
  266. 2183 GOTO 2180
  267. 2190 PRINT"AND YOU GET FED TO ";MID$(D$,Q*10-9,10):GOTO 1481
  268. 2200 PRINT"AND YOU GET STEPPED ON BY THE WIZARD"
  269. 2210 PRINT"    S Q U I S H  ! !":GOTO1481
  270. 2220 PRINT"IN THIS GAME YOU BECOME A HOBBIT THIEF"
  271. 2222 PRINT"TRYING TO STEAL THE ORB OF ZOT FROM"
  272. 2224 PRINT"THE CASTLE OF THE EVIL WIZARD."
  273. 2226 INPUT"HIT ENTER TO CONTINUE";O$:CLS
  274. 2228 PRINT"THE CASTLE IS A (9 X 9) MATRIX FILLED"
  275. 2230 PRINT"WITH MANY THINGS.  AMONG THESE"
  276. 2232 PRINT"THINGS (FOLLOWED BY THEIR NUMERIC REPRESENTATION"
  277. 2234 PRINT"ON THE MAP) ARE:"
  278. 2236 PRINT"GEMS (5), WARPS (11 THRU 99), SPARE FLARES (4)"
  279. 2238 PRINT"DEMONS (-1 THRU -12), AN ORACLE (2), AND"
  280. 2240 PRINT"AMULETS (100 THRU 700)."
  281. 2242 INPUT"HIT ENTER TO CONTINUE";O$:CLS
  282. 2244 PRINT"ALSO HIDDEN IN THE CASTLE ARE THE RUNESTAFF"
  283. 2246 PRINT"AND THE ORB OF ZOT.  THE ORB IS DISGUISED "
  284. 2248 PRINT"AS A WARP AND THE ONLY WAY TO GET IT IS"
  285. 2250 PRINT"TO TELEPORT INTO ITS ROOM DIRECTLY."
  286. 2252 PRINT"IF YOU TRY TO MOVE INTO ITS ROOM YOU WILL"
  287. 2254 PRINT"GO PAST IT IN THE SAME DIRECTION."
  288. 2256 PRINT"TO TELEPORT YOU MUST USE THE RUNESTAFF"
  289. 2258 PRINT"WHICH IS DISGUISED AS A DEMON. BE CAREFUL"
  290. 2260 PRINT"WHEN YOU TELEPORT, HOWEVER, BECAUSE YOU LOSE"
  291. 2262 PRINT"ALL YOUR AMULETS AND GEMS (NOTE: YOU MAY ALSO"
  292. 2263 PRINT"DROP SOME GEMS EACH TIME YOU MOVE)."
  293. 2264 INPUT"HIT ENTER TO CONTINUE ";O$:CLS
  294. 2266 PRINT"FIND THE ORB AS QUICKLY AS YOU CAN BECAUSE"
  295. 2268 PRINT"THE WIZARD WILL RETURN SHORTLY AND ONLY THE"
  296. 2270 PRINT"ORB CAN PREVENT HIM FROM DOING TERRIBLE THINGS"
  297. 2272 PRINT"TO YOU."
  298. 2280 REM
  299. 2290 INPUT"HIT ENTER TO CONTINUE";O$:CLS
  300. 2291 PRINT"THE LEGAL MOVES ARE:"
  301. 2300 PRINT"NORTH OR N"
  302. 2310 PRINT"SOUTH OR S"
  303. 2320 PRINT"EAST  OR E"
  304. 2330 PRINT"WEST OR W"
  305. 2340 PRINT"WAIT OR WT"
  306. 2350 PRINT"MAP OR M"
  307. 2360 PRINT"FLARE OR F"
  308. 2370 PRINT"LAMP OR L"
  309. 2380 PRINT"TELEPORT OR T"
  310. 2390 PRINT"KILL OR K"
  311. 2400 PRINT"QUIT OR Q"
  312. 2410 INPUT"HIT ENTER TO CONTINUE";O$:CLS
  313. 2420 GOTO 120
  314. 2430 REM A
  315. 2440 X=(RND*9):Y=(RND*9):IF H(X,Y)<>5 THEN 2440:RETURN
  316. 2450 REM B
  317. 2460 IF K>0 THEN 2470
  318. 2461 K=9
  319. 2470 IF K<10 THEN 2480
  320. 2471 K=1
  321. 2480 IF L>0 THEN 2490
  322. 2481 L=9
  323. 2490 IF L<10 THEN 2500
  324. 2491 L=1
  325. 2500 RETURN
  326. 9999 CLS:RUN "MENU.PGM"
  327. 65399 '** DONE - PRESS ENTER TO RETURN TO MENU **
  328. =9
  329. 2490 IF L<10 THEN 2500
  330. 2491 L=1
  331. 2500 R